$ONTEXT

This example illustrates the use of the rotated conic constraint
using the =C= construct. We show implementations using conic
constraints, nonlinear and linear constraints.

$OFFTEXT

$if not set nmax $set nmax 10

set n / n1*n%nmax% /;
parameter d(n), a(n), l(n), u(n);
scalar b;

d(n) = uniform(1,2);
a(n) = uniform (10,50);
l(n) = uniform(0.1,10);
u(n) = l(n) + uniform(0,12-l(n));

Variables x(n);
x.l(n) = uniform(l(n), u(n));
b = sum(n, x.l(n)*a(n));

x.lo(n) = l(n);
x.up(n) = u(n);

Variables t(n), z(n), obj;
Equations defobjc, defobj, e1, e2(n), cone(n), conenlp(n);

defobjc..     sum(n, d(n)*t(n)) =e= obj;
defobj..      sum(n, d(n)/x(n)) =e= obj;
e1..          sum(n, a(n)*x(n)) =l= b;
e2(n)..       z(n) =e= sqrt(2);

*cone(n)..     x(n) + t(n) =x= z(n);
* This is the "rotated quadratic cone"
cone(n)..     x(n) + t(n) =c= z(n);

conenlp(n)..  2*t(n)*x(n) =g= 2;

model clp  /defobjc, e1, e2, cone/;
model cnlp /defobjc, e1, conenlp/;
model orig /defobj, e1/;

solve clp  min obj using lp;
solve cnlp min obj using nlp;
solve orig min obj using nlp;