$title A Random Quadratic Assignment Problem

$ontext
Here we permit one to change a data item called size and a random number seed

A typical call causing the model to operater with size 6 and a
seed of 98765 would be done by calling GAMS in the following way:

  gams rqap user1=6 user2=98765 minlp=sbb optcr=0.0

$offtext

* If no size is specified we solve a QAP of size 5
$set size 5
*command below does not resets size if user1 is not on command line
*   with a non blank entry
$if not %gams.user1% == "" $set size %gams.user1%

* If no random seed is specified we set the seed to 123456
$set seed 123456
$if not %gams.user2% == "" $set seed %gams.user2%

*when size =6 this reads 1*6 thus if we put in user1=10 we get 1*10 here
set i / 1*%size% /;
alias (i,j,k,l);

Parameter d(i,j), f(i,j);

option seed=%seed%;

d(i,j)$(ord(i)<ord(j)) = trunc(uniform(0,100));
d(j,i)$(ord(i)<ord(j)) = d(i,j);

f(i,j)$(ord(i)<ord(j)) = trunc(uniform(0,100));
f(j,i)$(ord(i)<ord(j)) = f(i,j);

display d,f;

binary variable x(i,j);
variable z;

equation defobj
         assign1(i)
         assign2(j);

assign1(i).. sum(j,x(i,j)) =e= 1;
assign2(j).. sum(i,x(i,j)) =e= 1;

defobj..       z =e= sum((i,j,k,l), x(i,k)*x(j,l)*d(i,j)*f(k,l));

model qap / all /;
solve qap min z using minlp;