pfmaptst.gms : Checks files in distribution
Compares the list of existing files with the list of expected files.
Contributor: Lutz
For changes on all platforms
Small Model of Type: GAMS
<![CDATA[
$title 'Checks files in distribution' (GMSPFMAPTEST,SEQ=352)
$ontext
Compares the list of existing files with the list of expected files.
Contributor: Lutz
$offtext
$offlisting
$if not set GOLD $set GOLD 0
*For changes on all platforms
$set ALLPF (AIX,AXU,DAR,DII,LEX,LNX,SIS,SOL,SOX,WEX,WIN)
alias (*,ppp,prd,dir,fil);
*Sets containing input data
set curfil(prd,dir,fil) Files of current version
lstall(ppp,prd,dir,fil) Files of last version containing all platforms
lstfil(prd,dir,fil) Files of last version
curprd(prd) All products contained in current version
lstprd(prd) All products contained in last version
*Sets containing expected products/files
expprd(prd) Expected products
expfil(prd,dir,fil) Expected files
*Sets containing errors
nexprd(prd) Products being not expected but contained in current version
misprd(prd) Products missing in current version
drwprd(prd) Products dropped wrongly (dropped but not in previous version)
nexfil(prd,dir,fil) Files per product and directory being not expected but contained in current version
misfil(prd,dir,fil) Files per product and directory missing in current version
drwfil(prd,dir,fil) Files per product and directory dropped wrongly (dropped but not in previous version)
*Sets containing expexted changes
$onempty
newprd(ppp,prd) New products /
AIX . SCENSOLVER
DII . SCENSOLVER
LEX . SCENSOLVER
LNX . SCENSOLVER
SIS . SCENSOLVER
SOL . SCENSOLVER
SOX . SCENSOLVER
WEX . SCENSOLVER
WIN . SCENSOLVER
/
drpprd(ppp,prd) Dropped products /
/
$set SCENS_U "'gmsssdus.run','gmsssdux.out','optscensolver.def','optscensolver.html'"
$set SCENS_W "'gmsssd95.bat','gmsssdnt.cmd','gmsssdnx.exe','optscensolver.def','optscensolver.html'"
$onecho > modlib.txt
'maxcut.338','gqapsdp.339','pb16x7.inc','runcsdp.inc','tg207777.inc','trnssdp.340','two3mac.341'
$offecho
$onecho > tstlib.txt
'convert6.400','mcp08.401','assign2.402','macro01.403','gdx7.404','gdx8.405','gdxmerg2.406','scensol1.407'
$offecho
newfil(ppp,prd,dir,fil) New files per product and directory /
%ALLPF% .(ModelLibrary . './gamslib_ml'.(
$include modlib.txt
)
TestLibrary . './testlib_ml'.(
$include tstlib.txt
)
gamsAPI .('./apifiles/common'.'gamsglobals_mod.f90'
'./apifiles/gamsx'.('gamsxlfdefwrap.f90','gamsxlfdeflib.f90','gamsxlfdef.def','gamsxlfdef.f90'))
gdxAPI . './apifiles/gdx'.('gdxlfdefwrap.f90','gdxlfdeflib.f90','gdxlfdef.def','gdxlfdef.f90')
optionAPI . './apifiles/opt'.('optlfdefwrap.f90','optlfdeflib.f90','optlfdef.def','optlfdef.f90'))
AIX . SCENSOLVER .('.' .(%SCENS_U%,'libscndclib.so'),'./install'.'gmsssdun.dat')
DII .(GAMS . '.' . 'csdp'
SCENSOLVER .('.' .(%SCENS_U%,'libscndclib.dylib'),'./install'.'gmsssdun.dat'))
LEX .(GAMS . '.' .('csdp','libintlc.so.5','libintlc.so')
MOSEK . '.' .('libunwind.so','libunwind.so.5')
LINDOGLOBAL . '.' .('libunwind.so','libunwind.so.5')
SCENSOLVER .('.' .(%SCENS_U%,'libscndclib64.so'),'./install'.'gmsssdun.dat'))
LNX .(GAMS . '.' . 'csdp'
SCENSOLVER .('.' .(%SCENS_U%,'libscndclib.so'),'./install'.'gmsssdun.dat'))
SIS . SCENSOLVER .('.' .(%SCENS_U%,'libscndclib.so'),'./install'.'gmsssdun.dat')
SOL . SCENSOLVER .('.' .(%SCENS_U%,'libscndclib.so'),'./install'.'gmsssdun.dat')
SOX . SCENSOLVER .('.' .(%SCENS_U%,'libscndclib64.so'),'./install'.'gmsssdun.dat')
WEX .(GAMS . '.' . 'csdp.exe'
SCENSOLVER .('.' .(%SCENS_W%,'scndclib64.dll'),'./install'.('gmsssd95.dat','gmsssdnt.dat')))
WIN .(GAMS . '.' . 'csdp.exe'
SCENSOLVER .('.' .(%SCENS_W%,'scndclib.dll'),'./install'.('gmsssd95.dat','gmsssdnt.dat')))
/
drpfil(ppp,prd,dir,fil) Dropped files per product and directory /
LEX . GAMS . '.' .('libunwind.so','libunwind.so.5','libcxaguard.so.5','libcxaguard.so','libifcoremt.so.5','libifcoremt.so','libcprts.so.5','libcxa.so.5')
/
$offempty
;
$call rm -f tstlib.txt modlib.txt datalib.txt finlib.txt
$gdxin "%gams.sysdir%gmspfmap"
$load curfil=pfmap
$gdxin allpfmap
$load lstall=pfmap
$if %GOLD% == 1 $goto mkallpf
lstfil(prd,dir,fil)=lstall('%system.platform%',prd,dir,fil);
option curprd<curfil, lstprd<lstfil;
expprd(prd) = lstprd(prd) and not drpprd('%system.platform%',prd) or newprd('%system.platform%',prd);
expfil(prd,dir,fil) = lstfil(prd,dir,fil) and not (drpfil('%system.platform%',prd,dir,fil) or drpprd('%system.platform%',prd)) or newfil('%system.platform%',prd,dir,fil);
nexprd(curprd) = not expprd(curprd);
misprd(expprd) = not curprd(expprd);
drwprd(prd) = drpprd('%system.platform%',prd) and not lstprd(prd);
nexfil(curfil) = not expfil(curfil);
misfil(expfil) = not curfil(expfil);
drwfil(prd,dir,fil) = drpfil('%system.platform%',prd,dir,fil) and not lstfil(prd,dir,fil);
option nexfil:0:0:3,misfil:0:0:3,drwfil:0:0:3;
abort$(card(nexprd) + card(misprd) + card(drwprd) + card(nexfil) + card(misfil) + card(drwfil))
nexprd, misprd, drwprd, nexfil, misfil, drwfil;
$exit
$label mkallpf
set curall(ppp,prd,dir,fil) Files of current version containing all platforms;
curall(ppp,prd,dir,fil) = lstall(ppp,prd,dir,fil) and not (drpfil(ppp,prd,dir,fil) or drpprd(ppp,prd)) or newfil(ppp,prd,dir,fil);
execute_unload 'allpfmap' curall=pfmap;
]]></plaintext></body></div>