hhmax.gms : A Household Maximization Problem

Description

No description.


Reference

  • Hosoe, N, Gasawa, K, and Hashimoto, H, Handbook of Computible General Equilibrium Modeling. University of Tokyo Press, Tokyo, Japan, 2004.

Small Model of Type : NLP


Category : GAMS Model library


Main file : hhmax.gms

$title A Household's Utility Max. Model in Ch. 3 (HHMAX,SEQ=274)

$onText
No description.


Hosoe, N, Gasawa, K, and Hashimoto, H
Handbook of Computible General Equilibrium Modeling
University of Tokyo Press, Tokyo, Japan, 2004

Keywords: nonlinear programming
$offText

Set
   i 'goods'   / BRD  'bread',   MLK  'milk'  /
   h 'factors' / CAP  'capital', LAB  'labor' /;

Parameter
   alpha(i) 'share parameter in utility function' / BRD  0.2, MLK  0.8 /
   px(i)    'price of the i-th good'              / BRD  1  , MLK  2   /
   pf(h)    'price of the h-th factor'            / CAP  2  , LAB  1   /
   FF(h)    'factor endowment'                    / CAP 10  , LAB 20   /;

Positive Variable X(i) 'consumption of the i-th good';

Variable UU 'utility';

Equation
   eqX(i) 'household demand function'
   obj    'utility function';

eqX(i).. X(i) =e= alpha(i)*sum(h, pf(h)*FF(h))/px(i);

obj..    UU   =e= prod(i, X(i)**alpha(i));

* Setting Lower Bounds on Variables to Avoid Division by Zero
X.lo(i) = 0.001;

Model HHmax / all /;

solve HHmax maximizing UU using nlp;