ps2_f_s.gms : Parts Supply Problem w/ 2 Types w/o and w/ Asymmetric Information

Description

Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
  to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
  Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
  March 2012.

 http://www.grips.ac.jp/r-center/en/discussion_papers/11-27/


References

  • Hashimoto, H, Hamada, K, and Hosoe, N, A Numerical Approachto the Contract Theory: The Case of Adverse Selection. GRIPS Discussion Papers, National Graduate Institute for Policy Studies, 2012.
  • Itoh, H, A Course in Contract Theory. Yuhikaku, Tokyo, 2003.

Small Model of Type : NLP


Category : GAMS Model library


Main file : ps2_f_s.gms

$Title Parts Supply Problem w/ 2 Types w/o & w/ Asymmetric Information (PS2_F_S,SEQ=358)

* Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
*   to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
*   Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
*   March 2012.
*
*  http://www.grips.ac.jp/r-center/en/discussion_papers/11-27/

Option limcol=0,limrow=0;

* Definition of Set
Set     i       type of supplier        /eff, inf/;
Alias (i,j);
* Definition of Parameters
Parameter
        theta(i)        efficiency      /eff    0.2
                                        inf     0.3/
        p(i)            probability of type
                                        /eff    0.2
                                        inf     0.8/;
Scalar  ru              reservation utility     /0/;

* Definition of Primal/Dual Variables
Positive Variable
        x(i)            quality
        b(i)            maker's revenue
        w(i)            price;
Variable
        Util            maker's utility;
Equation
        obj             maker's utility function
        rev(i)          maker's revenue function
        pc(i)           participation constraint
        ic(i,j)         incentive compatibility constraint;

* Specification of Equations
obj..   Util =e= sum(i, p(i)*(b(i)-w(i)));
rev(i)..b(i) =e= x(i)**(0.5);
pc(i).. w(i)-theta(i)*x(i) =g= ru;
ic(i,j)..w(i)-theta(i)*x(i) =g= w(j)-theta(i)*x(j);

* Setting Lower Bounds on Variables to Avoid Division by Zero
x.lo(i)=0.0001;

* Defining and Solving the Model
Model FB1 /obj,rev,pc/;
Solve FB1 maximizing Util using NLP;

Model SB1 /obj,rev,pc,ic/;
Solve SB1 maximizing Util using NLP;

* End of Model