ps2_s.gms : Parts Supply Problem w/ 2 Types w/ Asymmetric Information

Description

Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
March 2012.

http://www.grips.ac.jp/r-center/en/discussion_papers/11-27/

Keywords: nonlinear programming, contract theory


References

  • Hashimoto, H, Hamada, K, and Hosoe, N, A Numerical Approachto the Contract Theory: The Case of Adverse Selection. GRIPS Discussion Papers, National Graduate Institute for Policy Studies, 2012.
  • Itoh, H, A Course in Contract Theory. Yuhikaku, Tokyo, 2003.

Small Model of Type : NLP


Category : GAMS Model library


Main file : ps2_s.gms

$title Parts Supply Problem w/ 2 Types w/ Asymmetric Information (PS2_S,SEQ=362)

$onText
Hideo Hashimoto, Kojun Hamada, and Nobuhiro Hosoe, "A Numerical Approach
to the Contract Theory: the Case of Adverse Selection", GRIPS Discussion
Paper 11-27, National Graduate Institute for Policy Studies, Tokyo, Japan,
March 2012.

http://www.grips.ac.jp/r-center/en/discussion_papers/11-27/

Keywords: nonlinear programming, contract theory
$offText

option limCol = 0, limRow = 0;

Set i 'type of supplier' / eff, inf /;

Alias (i,j);

Parameter
   theta(i) 'efficiency'          / eff 0.2, inf 0.3 /
   p(i)     'probability of type' / eff 0.2, inf 0.8 /;

Scalar ru 'reservation utility' / 0 /;

* Definition of Primal/Dual Variables
Positive Variable
   x(i) "quality"
   b(i) "maker's revenue"
   w(i) "price";

Variable Util "maker's utility";

Equation
   obj     "maker's utility function"
   rev(i)  "maker's revenue function"
   pc(i)   "participation constraint"
   ic(i,j) "incentive compatibility constraint";

obj..     Util =e= sum(i, p(i)*(b(i) - w(i)));

rev(i)..  b(i) =e= x(i)**(0.5);

pc(i)..   w(i) - theta(i)*x(i) =g= ru;

ic(i,j).. w(i) - theta(i)*x(i) =g= w(j) - theta(i)*x(j);

* Setting Lower Bounds on Variables to Avoid Division by Zero
x.lo(i) = 0.0001;

Model SB1 / all /;

solve SB1 maximizing Util using nlp;