Gtc : Optimal Gas Transmission Compressor Design

Reference

  • Neculai Andrei, Nonlinear Optimization Applications Using the GAMS Technology,Springer Optimization and Its Applications, Model Gtc (5.11) in chapter Applications of Mechanical Engineering , 2013

Category : GAMS NOA library


Mainfile : gtc.gms

$Ontext
Gas transmission compressor design.

Beightler, C., Phillips, D., Applied geometric programming. John Wiley
and Sons, New York, 1976.

Ali, M., Pant, M., Singh, V.P., Two modified differential evolution
algorithms and their applications to engineering design problems.
World Journal of Modeling and Simulation, vol.6, 2010, pp.72-80.
(Real life problem F1)
$Offtext

Variables x1, x2, x3, obj;
Equations eobj;

eobj.. obj =e= 861000*(sqrt(x1))*x2*(x3**(-2/3))/sqrt(x2*x2-1)+
                36900*x3 +
                772000000*(x2**(0.219))/x1 -
                765430000/x1;

*Bound on variables:
x1.lo = 10;    x1.up = 55;
x2.lo = 1.1;   x2.up = 2;
x3.lo = 10;    x3.up = 40;

Model gtc /all/;

$iftheni x%mode%==xbook
$onecho >bench.opt
  solvers conopt knitro minos snopt
$offecho
gtc.optfile=1;
option nlp=bench;
$endif

Solve gtc minimizing obj using nlp;

$iftheni x%mode%==xbook
file gtcd /gtc1.dat/
put gtcd;
put x1.l:15:7, x2.l:15:7, x3.l:15:7 /;
put obj.l:15:7 /;
$endif

* End gtc