convert11.gms : CONVERT test suite - check interval evaluator in ConvertD

Description

Check ConvertD's interval evaluator

Contributor: Steve Dirkse


Small Model of Type : GAMS


Category : GAMS Test library


Main file : convert11.gms

$TITLE CONVERT test suite - check interval evaluator in ConvertD (CONVERT11,SEQ=669)

$ontext
Check ConvertD's interval evaluator

Contributor: Steve Dirkse
$offtext


variables
  x  / lo  1, up 4 /
  y  / lo -1, up 8 /
  z
  ;
equations
  f  'e1'
  g  'e2'
  h  'e3'
  ;

f .. sqr(x-2) + sqr(y-2) =e= 2*z;
g .. x + y =L= 1;
h .. exp(.25*x) + exp(.25*y) =G= -1;

model m / f, g, h /;

solve m using nlp min z;

$set JAC  jac11.gdx
$set JAC_ jac11_.gdx

$onecho > convertd.opt
jacobian     %JAC%
intervalEval yes
$offecho
option nlp = convertd;
m.optfile = 1;

execute 'rm -f %JAC%';
solve m using nlp min z;

execute '=test -e %JAC%';
abort$errorlevel 'we did not find Jacobian file %JAC% after ConvertD ran';
execute 'gdxdiff %JAC% %JAC_% relEps=2e-15 > %system.nullfile%';
abort$errorlevel 'Unexpected result diffing %JAC% with %JAC_%';